react-native-background-geolocation: duplicate entry: com/google/android/gms/auth/api/signin/zzc.class

With latest version coming soon, you’ll need to use minimum 11.2.0.

Latest play-services version (released Nov 6) is 11.6.0. It’s always preferable to use latest version.

Wanted to post my working build.gradle file. See all lines with ‘//Added this’

apply plugin: 'com.android.application'

android {
	compileSdkVersion 25
	buildToolsVersion '25.0.2'

	defaultConfig {
		applicationId "com.thirtyEigthSS.FCEChauffeur"
		minSdkVersion 19
		targetSdkVersion 25
		versionCode 1
		versionName "1.0"
		multiDexEnabled true
		ndk {
			abiFilters 'armeabi-v7a', 'x86'
		}
		manifestPlaceholders = [
			'appAuthRedirectScheme': 'com.thirtyEigthSS.FCEChauffeur'
		]
	}
	buildTypes {
		release {
			minifyEnabled false
			proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
		}
	}
	dexOptions {
		javaMaxHeapSize "8g"
	}
	lintOptions {
		abortOnError false
	}
	//Added This
	packagingOptions {
		exclude 'META-INF/maven/com.squareup.okhttp3/okhttp/pom.properties'
		exclude 'META-INF/maven/com.squareup.okio/okio/pom.xml'
		exclude 'META-INF/maven/com.squareup.okhttp3/okhttp/pom.xml'
		exclude 'META-INF/maven/com.squareup.okio/okio/pom.properties'
	}
	//End - Added This
}

task exponentPrebuildStep(type: Exec) {
	workingDir '../../'

	if (System.getProperty('os.name').toLowerCase().contains('windows')) {
		commandLine 'cmd', '/c', '.\\.expo-source\\android\\detach-scripts\\prepare-detached-build.bat'
	} else {
		commandLine './.expo-source/android/detach-scripts/prepare-detached-build.sh'
	}
}
preBuild.dependsOn exponentPrebuildStep

repositories{
	flatDir{
		dirs 'libs'
		dirs "../../node_modules/react-native-background-geolocation/android/libs"
	}
	mavenLocal()
	maven { url 'https://maven.fabric.io/public' }
}


dependencies {
	compile fileTree(dir: 'libs', include: ['*.jar'])
	testCompile 'junit:junit:4.12'
	compile 'com.android.support:appcompat-v7:25.3.1'
	compile 'com.android.support:multidex:1.0.1'

	compile('host.exp.exponent:expoview:22.0.0@aar') {
		exclude group: 'com.facebook.android', module: 'facebook-android-sdk'
		exclude group: 'com.facebook.android', module: 'audience-network-sdk'
		exclude group: 'io.nlopez.smartlocation', module: 'library'

		exclude group: 'com.google.android.gms'  //Added This

		transitive = true;
	}

	//Added This
	compile ("com.google.android.gms:play-services-base:11.0.4") {
		force = true;
	}
	compile ("com.google.android.gms:play-services-maps:11.0.4") {
			force = true;
	}
	compile ("com.google.android.gms:play-services-gcm:11.0.4") {
			force = true;
	}
	compile ("com.google.android.gms:play-services-location:11.0.4") {
			force = true;
	}
	compile ("com.google.android.gms:play-services-auth:11.0.4") {
			force = true;
	}
	compile ("com.google.android.gms:play-services-analytics:11.0.4") {
			force = true;
	}
	compile ("com.google.android.gms:play-services-ads:11.0.4") {
			force = true;
	}
	compile ('com.google.android.gms:play-services-wallet:11.0.4') {
			force = true;
	}
	//End - Added This

	compile ('com.facebook.android:facebook-android-sdk:4.+') {
		exclude module: 'bolts-android'
	}
	compile('com.facebook.android:audience-network-sdk:4.+') {
		exclude module: 'play-services-ads'
	}
	compile('io.nlopez.smartlocation:library:3.2.11') {
		transitive = false
	}

	compile(name: 'tslocationmanager', ext: 'aar') 
	compile(project(':react-native-background-geolocation')) 
}